單片機與24C02的通訊

I2C(Inter－Integrated Circuit)總線是一種由PHILIPS公司開發(fā)的兩線式串行總線，用于連接微控制器及其外圍設(shè)備。

I2C的特點：

I2C總線的長度可高達25英尺，并且能夠以10Kbps的最大傳輸速率支持40個組件;支持多主控(multimastering)，其中任何能夠進行發(fā)送和接收的設(shè)備都可以成為主總線。一個主控能夠控制信號的傳輸和時鐘頻率。當然，在任何時間點上只能有一個主控。

I2C總線工作原理：

I2C總線是由數(shù)據(jù)線SDA和時鐘SCL構(gòu)成的串行總線，可發(fā)送和接收數(shù)據(jù)。在CPU與被控IC之間、IC與IC之間進行雙向傳送，最高傳送速率100kbps。各種被控制電路均并聯(lián)在這條總線上，但就像電話機一樣只有撥通各自的號碼才能工作，所以每個電路和模塊都有唯一的地址，在信息的傳輸過程中，I2C總線上并接的每一模塊電路既是主控器（或被控器），又是發(fā)送器（或接收器），這取決于它所要完成的功能。CPU發(fā)出的控制信號分為地址碼和控制量兩部分，地址碼用來選址，即接通需要控制的電路，確定控制的種類；控制量決定該調(diào)整的類別（如對比度、亮度等）及需要調(diào)整的量。這樣，各控制電路雖然掛在同一條總線上，卻彼此獨立，互不相關(guān)。

I2C總線在傳送數(shù)據(jù)過程中共有三種類型信號，它們分別是：開始信號、結(jié)束信號和應答信號。
開始信號：SCL為高電平時，SDA由高電平向低電平跳變，開始傳送數(shù)據(jù)。
結(jié)束信號：SCL為高電平時，SDA由低電平向高電平跳變，結(jié)束傳送數(shù)據(jù)。
應答信號：接收數(shù)據(jù)的IC在接收到8bit數(shù)據(jù)后，向發(fā)送數(shù)據(jù)的IC發(fā)出特定的低電平脈沖，表示已收到數(shù)據(jù)。CPU向受控單元發(fā)出一個信號后，等待受控單元發(fā)出一個應答信號，CPU接收到應答信號后，根據(jù)實際情況作出是否繼續(xù)傳遞信號的判斷。若未收到應答信號，由判斷為受控單元出現(xiàn)故障。

AT24C02的工作原理：

1.AT24C02的地址

2.AT24C02的開始和結(jié)束信號

3.AT24C02的應答信號：無論主從，每接收1個字節(jié)都要給出1個應答信號

4.AT24C02的容量:8個字節(jié)為一頁，共32頁，地址范圍為00H~FFH，即00H~07H為第一頁，08H~0FH為第二頁，以此類推。在連續(xù)讀寫時，若讀取地址超過單頁的第八個地址，則又從該頁的第一個地址循環(huán)開始。

5.AT24C02的讀寫：只有在SCL置低時，方可改變SDA的值，在SCL高電平期間，SDA需保持不變

A.寫入單個字節(jié)

B.連續(xù)寫入字節(jié)，當寫入到該頁最后一個地址單元時，再從該頁的起始單元寫入，如此反復。

C.AT24C02當前指針地址讀一個字節(jié)

D.指定AT24C02的內(nèi)存地址讀取一個字節(jié)

E.在當前AT24C02的地址指針位置開始，順序讀取多個字節(jié)，讀取到該頁最后一個字節(jié)時，再從該頁的第一個字節(jié)循環(huán)讀取

單片機與AT24C02通訊范例：

SCL EQU P3.6 ;定義SCL引腳
SDA EQU P3.7 ;定義SDA引腳

ORG 0000H
AJMP MAIN
ORG 0030H

START: SETB SDA ;開始信號
SETB SCL
CLR SDA
CLR SCL
RET

STOP: CLR SDA ;結(jié)束信號
SETB SCL
SETB SDA
RET

SEND: MOV R0,#08H ; 單片機向24C02寫入單字節(jié)子程序，1個bit1個bit地寫，連續(xù)寫8個
SEND0: RLC A
MOV SDA,C
SETB SCL
CLR SCL
DJNZ R0,SEND0
RET

REV: MOV R0,#08H ; 單片機從24C02讀取單字節(jié)子程序，1個bit接1個bit地讀，連續(xù)8個
REV0: MOV C,SDA
RLC A
SETB SCL
CLR SCL
DJNZ R0,REV0
RET

DELAY:MOV R6,#40 ; 用于結(jié)束信號的延時，在我的系統(tǒng)上少于1600us還不行，怪事
D1: MOV R7,#40
D2: DJNZ R7,D2
DJNZ R6,D1
RET

ACK : SETB SCL ; 24C02的應答信號
;CLR SDA ; 接收1個字節(jié)后自動產(chǎn)生，無需給出
CLR SCL
RET

ACK0: CLR SDA ; 單片機的應答信號，需要單片機主動給出
SETB SCL
CLR SCL
SETB SDA ; 這一步不可省略，請仔細看時序圖
RET

MAIN: MOV DPTR,#TABLE

ACALL START ; 開始信號
MOV A,#0A0H ; 輸入24C02地址及寫入信號，因為I2C總線上只有24C02這個器件，所以A0,A1,A2接地
ACALL SEND ; 發(fā)送到24C02
ACALL ACK ; 等待24C02的應答

MOV A,#00H ; 輸入24C02的地址指針，即寫入24C02的32頁地址段中的起始位置
ACALL SEND ; 發(fā)送到24C02
ACALL ACK ; 等待24C02的應答

MOV R4,#00H ;此程序段功能為連續(xù)寫入8個字節(jié)
MOV R5,#08H
WRITE: MOV A,R4
MOVC A,@A+DPTR
ACALL SEND
ACALL ACK
INC R4
DJNZ R5,WRITE
ACALL STOP ;寫完后發(fā)出結(jié)束信號
ACALL DELAY

ACALL START ; 送出開始信號，進入指定24C02地址中讀取單個字節(jié)模式
MOV A,#0A0H ; 輸入24C02地址及寫入信號
ACALL SEND ; 發(fā)送到24C02
ACALL ACK ; 等待24C02應答

MOV A,#00H ; 輸入要在24C02中讀取的數(shù)據(jù)的指定地址
ACALL SEND ; 發(fā)送到24C02
ACALL ACK ; 等待24C02應答

ACALL START ; 再次送出開始信號，準備讀取上面指定的24C02內(nèi)存單元
MOV A,#0A1H ; 輸入24C02地址及讀取信號
ACALL SEND ; 發(fā)送到24C02
ACALL ACK ; 等待24C02應答

ACALL REV ; 調(diào)用讀取單個字節(jié)子程序
;ACALL ACK ; NO ACK ，指定地址讀取單個字節(jié)模式不需要ACK
ACALL STOP ; 結(jié)束信號
ACALL DELAY
MOV 50H,A ; 將讀取到數(shù)據(jù)存入單片機50H地址中

ACALL START ; 發(fā)送開始信號，進入連續(xù)讀取數(shù)據(jù)模式
MOV A,#0A1H ; 輸入24C02地址及讀取信號
ACALL SEND ; 發(fā)送到24C02
ACALL ACK ; 等待24C02應答

MOV R2,#07 ; 緊接上面的地址后連續(xù)讀取7個字節(jié)
MOV R1,#51H ; 放入單片機的51H~57H地址單元
READ: ACALL REV
ACALL ACK0
MOV @R1,A
INC R1
DJNZ R2,READ
ACALL STOP
ACALL DELAY

LIGHT: MOV R1,#50H ; 從單片機的50H~57H單元中提取剛才存入的數(shù)據(jù)，顯示在數(shù)碼管上
MOV R2,#08H
MOV A,#0FEH
LOOP: MOV P1,A
MOV P0,@R1
INC R1
RL A
ACALL DEL
MOV P1,#0FFH
DJNZ R2,LOOP
AJMP LIGHT

DEL :MOV R4,#20 ;數(shù)碼管顯示的延時
D3: MOV R5,#20
D4: DJNZ R5,D4
DJNZ R4,D3
RET

TABLE: DB 0C0H,0F9H,0A4H,0B0H,099H,092H,082H,0F8H
END

;uchar code tab[]={0xc0,0xf9,0xa4,0xb0,0x99,;0,1,2,3,4,
;0x92,0x82,0xf8,0x80,0x90,;5,6,7,8,9,
;0x88,0x83,0xc6,0xa1,0x86,;A,B,C,D,E,
;0x8e,0x8c,0xc1,0xce,0x91,
;0x00,0xff}; //0-f,p,u,t,y,8.,滅共陽極數(shù)碼管顯示段碼