ARM處理器架構(gòu)-----協(xié)處理器

此控制寄存器中的兩個位提供目標和主機調(diào)試器之間的同步握手：

位 1（W 位） 從目標的角度表示通信數(shù)據(jù)寫入寄存器是否空閑：

W = 0 目標應(yīng)用程序可以寫入新數(shù)據(jù)。

W = 1 主機調(diào)試器可以從寫入寄存器中掃描出新數(shù)據(jù)。

位 0（R 位） 從目標的角度表示通信數(shù)據(jù)讀取寄存器中是否有新數(shù)據(jù)：

R = 1 有新數(shù)據(jù)，目標應(yīng)用程序可以讀取。

R = 0 主機調(diào)試器可以將新數(shù)據(jù)掃描到讀取寄存器中。

注意

調(diào)試器不能利用協(xié)處理器 14 直接訪問調(diào)試通信通道，因為這對調(diào)試器無意義。 但調(diào)試器可使用掃描鏈讀寫 DCC 寄存器。 DCC 數(shù)據(jù)和控制寄存器可映射到 EmbeddedICE 邏輯單元中的地址。 若要查看 EmbeddedICE 邏輯寄存器，請參閱您的調(diào)試器和調(diào)試目標的相關(guān)文檔。

通信數(shù)據(jù)讀取寄存器

用于接收來自調(diào)試器的數(shù)據(jù)的 32 位寬寄存器。 以下指令在 Rd 中返

回讀取寄存器的值：

MRC p14, 0, Rd, c1, c0

通信數(shù)據(jù)寫入寄存器

用于向調(diào)試器發(fā)送數(shù)據(jù)的 32 位寬寄存器。 以下指令將 Rn 中的值寫

到寫入寄存器中：

MCR p14, 0, Rn, c1, c0

注意

有關(guān)訪問 ARM10 和 ARM11 內(nèi)核 DCC 寄存器的信息，請參閱相應(yīng)的技術(shù)參考手冊。 ARM9 之后的各處理器中，所用指令、狀態(tài)位位置以及對狀態(tài)位的解釋都有所不同。

目標到調(diào)試器的通信

這是運行于 ARM 內(nèi)核上的應(yīng)用程序與運行于主機上的調(diào)試器之間的通信事件順序：

1. 目標應(yīng)用程序檢查 DCC 寫入寄存器是否空閑可用。 為此，目標應(yīng)用程序使用 MRC 指令讀取調(diào)試通信通道控制寄存器，以檢查 W 位是否已清除。

2. 如果 W 位已清除，則通信數(shù)據(jù)寫入寄存器已清空，應(yīng)用程序?qū)f(xié)處理器14 ，使用 MCR 指令將字寫入通信數(shù)據(jù)寫入寄存器。 寫入寄存器操作會自動設(shè)置W 位。如果 W 位已設(shè)置，則表明調(diào)試器尚未清空通信數(shù)據(jù)寫入寄存器。此時，如果應(yīng)用程序需要發(fā)送另一個字，它必須輪詢 W 位，直到它已清除。

3. 調(diào)試器通過掃描鏈 2 輪詢通信數(shù)據(jù)控制寄存器。 如果調(diào)試器發(fā)現(xiàn) W 位已設(shè)置，則它可以讀 DCC 數(shù)據(jù)寄存器，以讀取應(yīng)用程序發(fā)送的信息。 讀取數(shù)據(jù)的進程會自動清除通信數(shù)據(jù)控制寄存器中的 W 位。

以下代碼顯示了這一過程

AREA OutChannel, CODE, READONLY

ENTRY

MOV r1,#3 ; Number of words to send

ADR r2, outdata ; Address of data to send

pollout

MRC p14,0,r0,c0,c0 ; Read control register

TST r0, #2

BNE pollout ; if W set, register still full

write

LDR r3,[r2],#4 ; Read word from outdata

; into r3 and update the pointer

MCR p14,0,r3,c1,c0 ; Write word from r3

SUBS r1,r1,#1 ; Update counter

BNE pollout ; Loop if more words to be written

MOV r0, #0x18 ; Angel_SWIreason_ReportException

LDR r1, =0x20026 ; ADP_Stopped_ApplicationExit

SVC 0x123456 ; ARM semihosting (formerly SWI)

outdata

DCB "Hello there!"

END

調(diào)試器到目標的通信

這是運行于主機上的調(diào)試器向運行于內(nèi)核上的應(yīng)用程序傳輸消息的事件順序：

1. 調(diào)試器輪詢通信數(shù)據(jù)控制寄存器的 R 位。 如果 R 位已清除，則通信數(shù)據(jù)讀取寄存器已清空，可將數(shù)據(jù)寫入此寄存器，以供目標應(yīng)用程序讀取。

2. 調(diào)試器通過掃描鏈 2 將數(shù)據(jù)掃描到通信數(shù)據(jù)讀取寄存器中。 此操作會自動設(shè)置通信數(shù)據(jù)控制寄存器中的 R 位。

3. 目標應(yīng)用程序輪詢通信數(shù)據(jù)控制寄存器中的 R 位。 如果該位已經(jīng)設(shè)置，則通信數(shù)據(jù)讀取寄存器中已經(jīng)有數(shù)據(jù)，應(yīng)用程序可使用 MRC 指令從協(xié)處理器14 讀取該數(shù)據(jù)。 同時，讀取指令還會清除 R 位。

以下顯示的目標應(yīng)用程序代碼演示了這一過程

AREA InChannel, CODE, READONLY

ENTRY

MOV r1,#3 ; Number of words to read

LDR r2, =indata ; Address to store data read

pollin

MRC p14,0,r0,c0,c0 ; Read control register

TST r0, #1

BEQ pollin ; If R bit clear then loop

read

MRC p14,0,r3,c1,c0 ; read word into r3

STR r3,[r2],#4 ; Store to memory and

; update pointer

SUBS r1,r1,#1 ; Update counter

BNE pollin ; Loop if more words to read

MOV r0, #0x18 ; Angel_SWIreason_ReportException

LDR r1, =0x20026 ; ADP_Stopped_ApplicationExit

SVC 0x123456 ; ARM semihosting (formerly SWI)

AREA Storage, DATA, READWRITE

indata

DCB "Duffmessage#"

END

CP15系統(tǒng)控制協(xié)處理器

CP15 —系統(tǒng)控制協(xié)處理器 （the system control coprocessor）他通過協(xié)處理器指令MCR和MRC提供具體的寄存器來配置和控制caches、MMU、保護系統(tǒng)、配置時鐘模式（在bootloader時鐘初始化用到）

CP15的寄存器只能被MRC和MCR（Move to Coprocessor from ARM Register ）指令訪問

MCR{cond} p15,,,,,

MRC{cond} p15,,,,,

其中L位用來區(qū)分MCR(L=1)和MRC(L=0)操作. CP15包括15個具體的寄存器如下

-R0：ID號寄存器

-R0：緩存類型寄存器

-R1：控制寄存器

-R2：轉(zhuǎn)換表基址寄存器（Translation Table Base --TTB）

-R3：域訪問控制寄存器（Domain access control ）

-R4：保留

-R5：異常狀態(tài)寄存器（fault status -FSR）

-R6：異常地址寄存器（fault address -FAR）

-R7：緩存操作寄存器

-R8：TLB操作寄存器

-R9：緩存鎖定寄存器

-R10：TLB 鎖定寄存器

-R11-12&14：保留

-R13：處理器ID

-R15：測試配置寄存器 2-24

要注意有2個R0，根據(jù)MCR操作數(shù)的不同傳送不同的值，這也一個只讀寄存器

-R0：ID號寄存器 這是一個只讀寄存器，返回一個32位的設(shè)備ID號，具體功能參考ARM各個系列型號的的CP15 Register 0說明.

MRC p15, 0, , c0, c0, {0, 3-7} ;returns ID

以下為CP15的一些應(yīng)用示例

U32 ARM_CP15_DeviceIDRead(void)

{

U32 id;

__asm { MRC P15, 0, id, c0, c0; }

return id;

}

void ARM_CP15_SetPageTableBase(P_U32 TableAddress)

{

__asm { MCR P15, 0, TableAddress, c2, c0, 0; }

}

void ARM_CP15_SetDomainAccessControl(U32 flags)

{

__asm { MCR P15, 0, flags, c3, c0, 0; }

}

void ARM_CP15_ICacheFlush()

{

unsigned long dummy;

__asm { MCR p15, 0, dummy, c7, c5, 0; }

}

void ARM_CP15_DCacheFlush()

{

unsigned long dummy;

__asm { MCR p15, 0, dummy, c7, c6, 0; }

}

void ARM_CP15_CacheFlush()

{

unsigned long dummy;

__asm { MCR p15, 0, dummy, c7, c7, 0; }

}

void ARM_CP15_TLBFlush(void)

{

unsigned long dummy;

__asm { MCR P15, 0, dummy, c8, c7, 0; }

}

void ARM_CP15_ControlRegisterWrite(U32 flags)

{

__asm { MCR P15, 0, flags, c1, c0; }

}

void ARM_CP15_ControlRegisterOR(U32 flag)

{

__asm {

mrc p15,0,r0,c1,c0,0

mov r2,flag

orr r0,r2,r0

mcr p15,0,r0,c1,c0,0

}

}

void ARM_CP15_ControlRegisterAND(U32 flag)

{

__asm {

mrc p15,0,r0,c1,c0,0

mov r2,flag

and r0,r2,r0

mcr p15,0,r0,c1,c0,0

}

}

void ARM_MMU_Init(P_U32 TableAddress)

{

ARM_CP15_TLBFlush();

ARM_CP15_CacheFlush();

ARM_CP15_SetDomainAccessControl(0xFFFFFFFF);

ARM_CP15_SetPageTableBase(TableAddress);

}

void Enable_MMU (void)

{

__asm {

mrc p15,0,r0,c1,c0,0

mov r2, #0x00000001

orr r0,r2,r0

mcr p15,0,r0,c1,c0,0

}

printf("MMU enabledn");

}

void Disable_MMU (void)

{

__asm {

mrc p15,0,r0,c1,c0,0

mov r2, #0xFFFFFFFE

and r0,r2,r0

mcr p15,0,r0,c1,c0,0

}

printf("MMU disabledn");

}