零基礎：學51單片機定時器
加入技術交流群
在這里，小編帶你一起從零開始學51單片機定時器?；?a class="contentlabel" href="http://m.butianyuan.cn/news/listbylabel/label/單片機">單片機的定時器電路原理圖如下所示：
我們學單片機是首先學的就是 led 閃爍，那是用延時程序做的，現(xiàn)在回想起來，這樣做不很恰當，為什么呢?我們的主程序做了燈的閃爍，就不能再干其它的事了，難道單片機只能這樣工作嗎?當然不是，我們能用定時器來實現(xiàn)燈的閃爍的功能。
例 1：查詢方式
ORG 0000H
AJMP START
ORG 30H
START:
MOV P1,#0FFH ;關所 燈
MOV TMOD,#00000001B ;定時/計數(shù)器 0 工作于方式 1
MOV TH0,#15H
MOV TL0,#0A0H ;即數(shù) 5536
SETB TR0 ;定時/計數(shù)器 0 開始運行
LOOP:JBC TF0,NEXT ;如果 TF0 等于 1，則清 TF0 并轉 NEXT 處
AJMP LOOP ;不然跳轉到 LOOP 處運行
NEXT:CPL P1.0
MOV TH0,#15H
MOV TL0,#9FH;重置定時/計數(shù)器的初值
AJMP LOOP
END AJMP LOOP
END
鍵入程序，看到了什么?燈在閃爍了，這可是用定時器做的，不再是主程序的循環(huán)了。簡單地分析一下程序，為什么用 JBC 呢?TF0 是定時/計數(shù)器 0 的溢出標記位，當定時器產(chǎn)生溢出后，該位由 0 變 1，所以查詢該位就可知宇時時間是否已到。該位為 1 后，要用軟件將標記位清 0，以便下一次定時是間到時該位由 0 變 1，所以用了 JBC 指令，該指位在判 1轉移的同時，還將該位清 0。
以上程序是能實現(xiàn)燈的閃爍了，可是主程序除了讓燈閃爍外，還是不能做其他的事啊!不，不對，我們能在 LOOP：……和 AJMP LOOP 指令之間插入一些指令來做其他的事情，只要保證執(zhí)行這些指令的時間少于定時時間就行了。那我們在用軟件延時程序的時候不是也能用一些指令來替代 DJNZ 嗎?是的，但是那就要求你精確計算所用指令的時間，然后再減去對應的 DJNZ 循環(huán)次數(shù)，很不方便，而現(xiàn)在只要求所用指令的時間少于定時時間就行，顯然要求低了。當然，這樣的辦法還是不好，所以我們常用以下的辦法來實現(xiàn)。
程序 2：用中斷實現(xiàn)
ORG 0000H
AJMP START
ORG 000BH ;定時器 0 的中斷向量地址
AJMP TIME0 ;跳轉到真正的定時器程序處
ORG 30H
START:
MOV P1,#0FFH ;關所 燈
MOV TMOD,#00000001B ;定時/計數(shù)器 0 工作于方式 1
MOV TH0,#15H
MOV TL0,#0A0H ;即數(shù) 5536
SETB EA ;開總中斷允許
SETB ET0 ;開定時/計數(shù)器 0 允許
SETB TR0 ;定時/計數(shù)器 0 開始運行
LOOP: AJMP LOOP ;真正工作時,這里可寫任意程序
TIME0: ;定時器 0 的中斷處理程序
PUSH ACC
PUSH PSW ;將 PSW 和 ACC 推入堆棧保護
CPL P1.0
MOV TH0,#15H
MOV TL0,#0A0H ;重置定時常數(shù)
POP PSW
POP ACC
RETI
END
上面的例程中，定時時間一到，TF0 由 0 變 1，就會引發(fā)中斷，CPU 將自動轉至 000B處尋找程序并執(zhí)行，由于留給定時器中斷的空間只有 8 個字節(jié)，顯然不足以寫下所有有中斷處理程序，所以在 000B 處安排一條跳轉指令，轉到實際處理中斷的程序處，這樣，中斷程序能寫在任意地方，也能寫任意長度了。進入定時中斷后，首先要保存當前的一些狀態(tài)，程序中只 演示了保存存 ACC 和 PSW，實際工作中應該根據(jù)需要將可能會改變的單元的值都推入堆棧進行保護(本程序中實際不需保存護任何值，這里只作個演示)。
上面的兩個單片機程序運行后，我們發(fā)現(xiàn)燈的閃爍非?？?，根本分辨不出來，只是視覺上感到燈有些晃動而已，為什么呢?我們能計算一下，定時器中預置的數(shù)是 5536，所以每計 60000 個脈沖就是定時時間到，這 60000 個脈沖的時間是多少呢?我們的晶體震蕩器 是12M，所以就是 60000 微秒，即 60 毫秒，因此速度是非?？斓摹Ｈ绻蚁雽崿F(xiàn)一個 1S 的定時，該怎么辦呢?在該晶體震蕩器瀕率下，最長的定時也就是 65。536 個毫秒啊!上面給出 一個例程。
ORG 0000H
AJMP START
ORG 000BH ;定時器 0 的中斷向量地址
AJMP TIME0 ;跳轉到真正的定時器程序處
ORG 30H
START:
MOV P1,#0FFH ;關所 燈
MOV 30H,#00H ;軟件計數(shù)器預清 0
MOV TMOD,#00000001B ;定時/計數(shù)器 0 工作于方式 1
MOV TH0,#3CH
MOV TL0,#0B0H ;即數(shù) 15536
SETB EA ;開總中斷允許
SETB ET0 ;開定時/計數(shù)器 0 允許
SETB TR0 ;定時/計數(shù)器 0 開始運行
LOOP: AJMP LOOP ;真正工作時,這里可寫任意程序
TIME0: ;定時器 0 的中斷處理程序
PUSH ACC
PUSH PSW ;將 PSW 和 ACC 推入堆棧保護
INC 30H
MOV A,30H
CJNE A,#20,T_RET ;30H 單元中的值到了 20 了嗎?
T_L1: CPL P1.0 ;到了,取反 P10
MOV 30H,#0 ;清軟件計數(shù)器
T_RET:
MOV TH0,#15H
MOV TL0,#9FH ;重置定時常數(shù)
POP PSW
POP ACC
RETI
END
先自己分析一下，看看是怎么實現(xiàn)的?這里采用了軟件計數(shù)器的概念，思路是這樣的，先用定時/計數(shù)器 0 做一個 50 毫秒的定時器，定時是間到了以后并不是立即取反 P10，而是將軟件計數(shù)器中的值加 1，如果軟件計數(shù)器計到了 20，就取反 P10，并清掉軟件計數(shù)器中的值，不然直接返回，這樣，就變成了 20 次定時中斷才取反一次 P10，因此定時時間就延長了成了 20*50 即 1000 毫秒了。
這個思路在工程中是非常有用的，有的時候我們需要若干個定時器，可 51 中總共才有 2個，怎么辦呢?其實，只要這幾個定時的時間有一定的公約數(shù)，我們就能用軟件定時器加以實現(xiàn)，如我要實現(xiàn) P10 口所接燈按 1S 每次，而 P11 口所接燈按 2S 每次閃爍，怎么實現(xiàn)呢?對了我們用兩個計數(shù)器，一個在它計到 20 時，取反 P10，并清零，就如上面所示，另一個計到 40 取反 P11，然后清 0，不就行了嗎?這部份的程序如下
ORG 0000H
AJMP START
ORG 000BH ;定時器 0 的中斷向量地址
AJMP TIME0 ;跳轉到真正的定時器程序處
ORG 30H
START:
MOV P1,#0FFH ;關所 燈
MOV 30H,#00H ;軟件計數(shù)器預清 0
MOV TMOD,#00000001B ;定時/計數(shù)器 0 工作于方式 1
MOV TH0,#3CH
MOV TL0,#0B0H ;即數(shù) 15536
SETB EA ;開總中斷允許
SETB ET0 ;開定時/計數(shù)器 0 允許
SETB TR0 ;定時/計數(shù)器 0 開始運行
LOOP: AJMP LOOP ;真正工作時,這里可寫任意程序
TIME0: ;定時器 0 的中斷處理程序
PUSH ACC
PUSH PSW ;將 PSW 和 ACC 推入堆棧保護
INC 30H
INC 31H ;兩個計數(shù)器都加 1
MOV A,30H
CJNE A,#20,T_NEXT ;30H 單元中的值到了 20 了嗎?
T_L1: CPL P1.0 ;到了,取反 P10
MOV 30H,#0 ;清軟件計數(shù)器
T_NEXT:
MOV A,31H
CJNE A,#40,T_RET ;31h 單元中的值到 40 了嗎?
T_L2:
CPL P1.1
MOV 31H,#0 ;到了,取反 P11,清計數(shù)器,返回
T_RET:
MOV TH0,#15H
MOV TL0,#9FH ;重置定時常數(shù)
POP PSW
POP ACC
RETI
END
評論