平凡單片機教學(xué) 第二十四講 鍵盤接口與編程

按鍵開關(guān)的抖動問題

組成鍵盤的按鍵有觸點式和非觸點式兩種，單片機中應(yīng)用的一般是由機械觸點構(gòu)成的。在下圖中，當(dāng)開關(guān)S未被按下時，P1。0輸入為高電平，S閉合后，P1。0輸入為低電平。由于按鍵是機械觸點，當(dāng)機械觸點斷開、閉合時，會有抖動動，P1。0輸入端的波形如圖2所示。這種抖動對于人來說是感覺不到的，但對計算機來說，則是完全可以感應(yīng)到的，因為計算機處理的速度是在微秒級，而機械抖動的時間至少是毫秒級，對計算機而言，這已是一個“漫長”的時間了。前面我們講到中斷時曾有個問題，就是說按鍵有時靈，有時不靈，其實就是這個原因，你只按了一次按鍵，可是計算機卻已執(zhí)行了多次中斷的過程，如果執(zhí)行的次數(shù)正好是奇數(shù)次，那么結(jié)果正如你所料，如果執(zhí)行的次數(shù)是偶數(shù)次，那就不對了。

圖1 圖2

為使CPU能正確地讀出P1口的狀態(tài)，對每一次按鍵只作一次響應(yīng)，就必須考慮如何去除抖動，常用的去抖動的方法有兩種：硬件方法和軟件方法。單片機中常用軟件法，因此，對于硬件方法我們不介紹。軟件法其實很簡單，就是在單片機獲得P1。0口為低的信息后，不是立即認定S1已被按下，而是延時10毫秒或更長一些時間后再次檢測P1。0口，如果仍為低，說明S1的確按下了，這實際上是避開了按鍵按下時的抖動時間。而在檢測到按鍵釋放后（P1。0為高）再延時5-10個毫秒，消除后沿的抖動，然后再對鍵值處理。不過一般情況下，我們通常不對按鍵釋放的后沿進行處理，實踐證明，也能滿足一定的要求。當(dāng)然，實際應(yīng)用中，對按鍵的要求也是千差萬別，要根據(jù)不同的需要來編制處理程序，但以上是消除鍵抖動的原則。

2.鍵盤與單片機的連接

圖3 圖4

1、通過1/0口連接。將每個按鍵的一端接到單片機的I/O口，另一端接地，這是最簡單的方法，如圖3所示是實驗板上按鍵的接法，四個按鍵分別接到P3.2 、P3.3、P3.4和P3.5。對于這種鍵各程序可以采用不斷查詢的方法，功能就是：檢測是否有鍵閉合，如有鍵閉合，則去除鍵抖動，判斷鍵號并轉(zhuǎn)入相應(yīng)的鍵處理。下面給出一個例程。其功能很簡單，四個鍵定義如下：

P3.2：開始，按此鍵則燈開始流動（由上而下）

P3.3：停止，按此鍵則停止流動，所有燈為暗

P3.4：上，按此鍵則燈由上向下流動

P3.5：下，按此鍵則燈由下向上流動

UpDown EQU 00H ;上下行標(biāo)志

StartEnd EQU 01H ;起動及停止標(biāo)志

LAMPCODE EQU 21H ;存放流動的數(shù)據(jù)代碼

ORG 0000H

AJMP MAIN

ORG 30H

MAIN:

MOV SP,#5FH

MOV P1,#0FFH

CLR UpDown ;啟動時處于向上的狀態(tài)

CLR StartEnd ;啟動時處于停止?fàn)顟B(tài)

MOV LAMPCODE,#0FEH ;單燈流動的代碼

LOOP:

ACALL KEY ;調(diào)用鍵盤程序

JNB F0,LNEXT ;如果無鍵按下，則繼續(xù)

ACALL KEYPROC ;否則調(diào)用鍵盤處理程序

LNEXT:

ACALL LAMP ;調(diào)用燈顯示程序

AJMP LOOP ;反復(fù)循環(huán)，主程序到此結(jié)束

;---------------------------------------

DELAY:

MOV R7,#100

D1: MOV R6,#100

DJNZ R6,$

DJNZ R7,D1

RET

;----------------------------------------延時程序，鍵盤處理中調(diào)用

KEYPROC:

MOV A,B ;從B寄存器中獲取鍵值

JB ACC.2,KeyStart ;分析鍵的代碼，某位被按下，則該位為1（因為在鍵盤程序中已取反）

JB ACC.3,KeyOver

JB ACC.4,KeyUp

JB ACC.5,KeyDown

AJMP KEY_RET

KeyStart:

SETB StartEnd ;第一個鍵按下后的處理

AJMP KEY_RET

KeyOver:

CLR StartEnd ;第二個鍵按下后的處理

AJMP KEY_RET

KeyUp: SETB UpDown ;第三個鍵按下后的處理

AJMP KEY_RET

KeyDown:

CLR UpDown ;第四個鍵按下后的處理

KEY_RET:RET

KEY:

CLR F0 ;清F0，表示無鍵按下。

ORL P3,#00111100B ;將P3口的接有鍵的四位置1

MOV A,P3 ;取P3的值

ORL A,#11000011B ;將其余4位置1

CPL A ;取反

JZ K_RET ;如果為0則一定無鍵按下

ACALL DELAY ;否則延時去鍵抖

ORL P3,#00111100B

MOV A,P3

ORL A,#11000011B

CPL A

JZ K_RET

MOV B,A ;確實有鍵按下，將鍵值存入B中

SETB F0 ;設(shè)置有鍵按下的標(biāo)志

K_RET:

ORL P3,#00111100B ;此處循環(huán)等待鍵的釋放

MOV A,P3

ORL A,#11000011B

CPL A

JZ K_RET1 ;直到讀取的數(shù)據(jù)取反后為0說明鍵釋放了，才從鍵盤處理程序中返回

AJMP K_RET

K_RET1:

RET

;-----------------------------------

D500MS: ;流水燈的延遲時間

PUSH PSW

SETB RS0

MOV R7,#200

D51: MOV R6,#250

D52: NOP

NOP

NOP

NOP

DJNZ R6,D52

DJNZ R7,D51

POP PSW

RET

;-----------------------------------

LAMP:

JB StartEnd,LampStart ;如果StartEnd=1，則啟動

MOV P1,#0FFH

AJMP LAMPRET ;否則關(guān)閉所有顯示，返回

LampStart:

JB UpDown,LAMPUP ;如果UpDown=1，則向上流動

MOV A,LAMPCODE

RL A ;實際就是左移位而已

MOV LAMPCODE,A

MOV P1,A

LCALL D500MS

AJMP LAMPRET

LAMPUP:

MOV A,LAMPCODE

RR A ;向下流動實際就是右移

MOV LAMPCODE,A

MOV P1,A

LCALL D500MS

LAMPRET:

RET

END

以上程序功能很簡單，但它演示了一個鍵盤處理程序的基本思路，程序本身很簡單，也不很實用，實際工作中還會有好多要考慮的因素，比如主循環(huán)每次都調(diào)用燈的循環(huán)程序，會造成按鍵反應(yīng)“遲鈍”，而如果一直按著鍵不放，則燈不會再流動，一直要到松開手為止，等等，大家可以仔細考慮一下這些問題，再想想有什么好的解決辦法。

2、采用中斷方式：如圖4所示。各個按鍵都接到一個與非上，當(dāng)有任何一個按鍵按下時，都會使與門輸出為低電平，從而引起單片機的中斷，它的好處是不用在主程序中不斷地循環(huán)查詢，如果有鍵按下，單片機再去做相應(yīng)的處理。